;UoM_X_dec_if_1d_ts4x_tbi
;
;Developed by:
;NMR Methodology Group
;University of Manchester
;
;Pure shift 1D experiment 
;     with BB heteronuclear and homonuclear decoupling 
;     with interferogram acquisition
;
;Data can be reconstructed using a macro available at http://nmr.chemistry.manchester.ac.uk
;
;References: C. Mycroft, M. Nilsson, G. A. Morris,L. Castanar, Simultaneous broadbroad suppression of homonuclear and heteronuclear couplings in 1H NMR spectroscopy
;
;Band-selection: (1) L. Castanar, P. Nolis, A. Virgili, T. Parella, Chem. Eur. J., 19, 17283-17286, (2013)
;                (2) J. Ying, J. Roche, A. Bax, J. Magn. Reson., 241, 97-102, (2014)
;                (3) R. W. Adams, L. Byrne, P. Kiraly, M. Foroozabdeh, L. Paudel, M. Nilsson, J. Clayden, G. A. Morris, Chem. Commun., 50, 2512, (2014)
;Interferogram:  (1) K. Zangger, H. Sterk, J. Magn. Reson., 124, 486-489, (1997)
;                (2) J. A. Aguilar, S. Faulkner, M. Nilsson, G. A. Morris, 49, 3901-3903, (2010)
;PSYCHE: 	       (1)  Foroozandeh, M.; Adams, R. W.; Meharry, N. J.; Jeannerat, D.; Nilsson, M.; Morris, G. A. Angew. Chem. Int. Ed. 2014, 53, 6990.
;
;THE USE OF WAVEMAKER IS RECOMMENDED 
; 
;Pure shift active spin refocusing options 
;       ZGOPTION= -DBS (Band-Selective)
;       ZGOPTION= -DZS (Zangger-Sterk)
;       ZGOPTION= -DdSALTIRE (PSYCHE) [used by default]
;
;Avance NEO Version
;Topspin.4x
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=
;
;%%%%%%%%%% WaveMaker Calculations %%%%%%%%%%
;sp15:wvm:X1_wurst-20:f2 wurst-20(cnst5 kHz, cnst3 ms; Q=cnst7, L2H)
;sp19:wvm:X2_wurst-20:f2 wurst-20(cnst5 kHz, cnst3 ms; Q=cnst7, H2L)
;sp31(p63,pl12):wvm:HXdec:f2 wurst-80(cnst5 kHz, cnst10 ms; Q=cnst8, L2H) ss=1.0 us;
;
;Constants definition
"d11=30m+1s/(cnst1)-1s/(cnst1)"
"d11=30m+1s/(cnst3)-1s/(cnst3)"
"d11=30m+1s/(cnst5)-1s/(cnst5)"
"d11=30m+1s/(cnst7)-1s/(cnst7)"
"d11=30m+1s/(cnst8)-1s/(cnst8)"
"d11=30m+1s/(cnst9)-1s/(cnst9)"
"d11=30m+1s/(cnst10)-1s/(cnst10)"
"cnst9=200/cnst1"
"p63=cnst10*1000" 
"plw12=spw31"

#include <Avance.incl>
#include <Delay.incl>
#include <Grad.incl>

define delay tauA
define delay tauB

;DELAYS
"d0=0.0"  
"in0=inf1/2"
"tauA=in0/2-p16-d16-50u"
"tauB=dw*2*cnst4" 
"d11=30m"
"d16=1m"
"d17=200u"

;PULSES
"p2=p1*2"
"p4=p3*2"
"p16=1m"
"p17=1m"
"p10=p40" 

; BAND-SELECTIVE PULSE
#ifdef BS
;sp12:wvm:H_rsnob:f1 rsnob(cnst12 Hz, cnst11 ppm; PA=0.5; NPOINTS=1000) ss=1.0us;
"spoff12=0"
"d11=30m+1s/(cnst11)-1s/(cnst11)"
"d11=30m+1s/(cnst12)-1s/(cnst12)"
"d11=30m"
#   endif

; ZANGGER-STERK PULSE
#ifdef ZS
;sp12:wvm:H_rsnob:f1 rsnob(cnst12 Hz, cnst11 ppm; PA=0.5; NPOINTS=1000) ss=1.0us; 
"spoff12=0"
"d11=30m+1s/(cnst11)-1s/(cnst11)"
"d11=30m+1s/(cnst12)-1s/(cnst12)"
"d11=30m"
#   endif

;SALTIRE PULSE
#   ifdef dSALTIRE
;Double Saltire pulse calculations
"cnst50=(cnst20/360)*sqrt((2*cnst21)/(p40/2000000))"
"p30=1000000.0/(cnst50*4)"
"cnst31= (p30/p1) * (p30/p1)"
"spw40=plw1/cnst31"
"spoff40=0"
#   endif

;ACQUISITION
"acqt0=0"
baseopt_echo

1 ze
  30m pl12:f2
2 30m do:f2
  50u BLKGRAMP
  50u LOCKH_OFF
  d1
  50u LOCKH_ON
  50u UNBLKGRAMP pl1:f1 pl2:f2

3  
 
if "d0==0.0" ;chunk 1
{
p1 ph1
}
else 
{
 "DELTA=d0/2-(p15/2)"
  p1 ph1
  DELTA pl0:f2
  (p15:sp15 ph4):f2
  DELTA
}
  tauA
  50u 
  p16:gp1 
  d16
  p2 ph2
  p16:gp1 
  d16
  50u  
  tauA

  tauB
  50u
  d17 pl0:f1
  p16:gp2 
  d16 
# ifdef BS
  10u
  (p12:sp12 ph3):f1
  10u
# endif
# ifdef ZS
  10u gron0
  (p12:sp12 ph3):f1
  10u groff
# endif
# ifdef dSALTIRE
  10u
 (center (p40:sp40 ph3):f1 (p10:gp10) )
  10u 
# endif
  d17 
  p16:gp2 
  d16
  50u BLKGRAMP pl12:f2

if "d0==0.0"
{
}
else 
{
  DELTA pl0:f2
  (p19:sp19 ph5):f2
  DELTA pl12:f2
}

  go=2 ph31 cpd2:f2
  30m do:f2 mc #0 to 2 F1QF(id0)
exit
  50u LOCKH_OFF

ph1= 0 0 0 0 1 1 1 1
ph2= 0 0 0 0 0 0 0 0 2 2 2 2 2 2 2 2
ph3= 0 1 2 3
ph4= 0
ph5= 0
ph31=0 2 0 2 1 3 1 3

;POWER LEVEL
;pl0  : f1 channel - zero power (0W)
;pl1  : f1 channel - power level for hard pulse (default) 
;pl2  : f2 channel - power level for hard pulse (default)
;pl12 : f2 channel - power level for adiabatic X decoupling sequence
;sp12 : f1 channel - power level for selective H 180 refocussing pulse (BS and ZS approach)
;sp15 : f2 channel - power level for the first adiabatic X 180 inversion pulse 
;sp19 : f2 channel - power level for the second adiabatic X 180 inversion pulse 
;sp40 : f1 channel - power level for double-saltire pulse (PSYCHE approach)

;PULSES
;p1  : f1 channel - 90 degree high power pulse 
;p2  : f1 channel - 180 degree high power pulse
;p3  : f2 channel - 90 degree high power pulse
;p4  : f2 channel - 180 degree high power pulse
;p10 : f1 channel - duration of weak gradient during double-saltire element (PSYCHE approach)
;p12 : f1 channel - duration of 180 H selective refocussing pulse (BS and ZS approach)
;p15 : f2 channel - duration of the first adiabatic pulse in X channel 
;p16 : f1 channel - duration of CTP gradients of hard H 180 pulse         [1 ms]
;p17 : f1 channel - duration of CTP gradients of selective H 180 pulse  [1 ms]
;p19 : f2 channel - duration of the second adiabatic pulse in X channel 
;p40 : f1 channel - duration of double-saltire element (PSYCHE approach)
;p63 : f2 channel  duration of the adiabatic pulse in CPD

;DELAYS
;d0  : incremented delay
;d1  : relaxation delay;  > 2 T1 	
;d16 : recovery delay for CTP gradients of hard 180 pulse       [1 ms]
;d17 : recovery delay                                                                 [200 us]
;tauA: delay according to chunk duration
;tauB: digital filter correction delay


;SHAPED PULSES
;spnam12: f1 channel - file name for the 1H 180 selective refocussing pulse (BS and ZS approach)     [RSNOB]
;spnam15: f2 channel - file name for the first adiabatic X inversion pulse   [WURST-20]
;spnam19: f2 channel - file name for the second adiabatic X inversion pulse  [WURST-20]
;spnam40: f1 channel - file name for the double-saltire pulse element (PSYCHE approach)   [SALTIRE]

;GRADIENTS
;gpz0: spatial encoding gradient during 1H 180 selective refocussing pulse (ZS approach)     [0.1-2%]
;gpz1: CTP gradient for hard 180 pulse      [79%]
;gpz2: CTP gradient for selective 180 pulse [47%]
;gpz10: weak gradient during double-saltire pulse element (PSYCHE approach)   [1-3%]
;gpnam1: SINE.100
;gpnam2: SINE.100
;gpnam10: RECT.1

;CONSTANTS
;cnst1 : largest J(HX) value [Hz]
;cnst3 : f2 channel - duration of adiabatic X inversion pulses [< 5 ms]
;cnst4 : number of drop points 		[4]
;cnst5 : f2 channel - bandwidth for adiabatic X pulses and decoupling sequence [kHz]
;cnst7 : f2 channel - Q factor for adiabatic 180 X inversion pulses [<5]
;cnst8 : f2 channel - Q factor for adiabatic X decoupling sequence [typically 2-3]
;cnst9 : f2 channel - recommended X decoupling sequence duration
;cnst10: Set as cnst9 (or <5-10 ms, depending on chunk duration)
;cnst11: f1 channel - chemical shift for BS selective pulse. If ZS: set as o1p (in ppm)
;cnst12: f1 channel - bandwidth for selective refocussing pulse (in Hz)
;cnst20: f1 channel - desired flip angle for double-saltire pulse element [10-25 degrees]
;cnst21: f1 channel - bandwidth of each saltire pulse [10000 Hz}

;OTHER
;TD1 : number of t1 increments	 [16-64]
;in0 : 1/(2 * SW) = DW
;nd0 : 2
;IN_F: chunk duration [us]
;MC2 : QF
;ns : 2 * n
;ds : 2
;BS - set cnst11 to peak of interest
;ZS and PSYCHE: set O1 on in the centre of the spectral window
;cpd2: p5m4sp180.2 (use wvm -a command for power parameters)